[CoD4] mp_peds_propel - OUT NOW!

[Pedsdude]

http://codjumper.com/maps/index2.php?game=cod4&ID=14

mp_peds_propel is finally released!

It took a considerable amount of time, and a large amount of thanks go to KS for, amongst other things, making the secret area room. Suffice to say, for those who have tried to hack my previous secret rooms, this will be like nothing you've ever seen before

[[SoE]_Zaitsev]

Awesome. Will check it out tomorrow.

[BlueDamselfly]

your room was very easy to hack, until I show you how!

very cool map tho, especially without saving, but just too easy if you do

[Soviet]

I find it very hard to believe that Peds actually made a map with 1121 lines of non-repetitive, efficient scripting. However, it doesn't surprise me at all that his map crashes the servers.

[Nightmare]

Allow me to say "owned".
I might install CoD4 to try this out though, but I haven't seen enough screenies to entice me.

[Pedsdude]

screenies

http://www.codjumper.com/maps/cod4/mp_p ... pel_ss.zip

As requested.

Also, would you be able to upload it for me on CoDFiles, please?

[Nightmare]

screenies

http://www.codjumper.com/maps/cod4/mp_p ... pel_ss.zip

As requested.

Also, would you be able to upload it for me on CoDFiles, please?

Sure, just send me a zip with the map, some pictures, and a readme file.
While looking through the pictures, I can't possibly make out how that would use up so much scripting, all there is, is a swinging boulder.
Must be a very badly scripted secret room.

[Pedsdude]

While looking through the pictures, I can't possibly make out how that would use up so much scripting, all there is, is a swinging boulder.
Must be a very badly scripted secret room.

It is predominantly the secret room. And I wouldn't say that it's particularly badly scripted, just that there is a LOT going on with it.

[[SoE]_Zaitsev]

Nice screenshots. Map looks like fun.

[Pedsdude]

OP edited to include screenshots.


------------------------------


Here's the .zip for CoDfiles:
http://www.codjumper.com/files/codfiles ... propel.zip

I suppose you'll have to name it "Ped's Propel", based on the way the CoD1 maps were named.

[Pedsdude]

lol

[[SoE]_Zaitsev]

LOL

[Drofder2004]

Challenge Accepted!

Code: Select all

main()
{
	maps\mp\_load::main();
	ambientPlay("amb_airplane0v1_lr");
	game["allies"] = "sas";
	game["axis"] = "spetsnaz";
	game["allies_soldiertype"] = "desert";
	game["axis_soldiertype"] = "desert";
	
	//These are used often!
	level.accepted1 = "874e8c2cb0df78a1059ad8d2bcae97e7";
	level.accepted2 = "adfe897a00c6633a9db95b9b12624d8a";
	level.accepted1 = "874e8c2cb0df78a1059ad8d2bcae97e7";
	swinger = getent ("swinger","targetname");
	swingertrig = getent ("swingertrig","targetname");
	swinger2 = getent ("swinger2","targetname");
	swinger2trig = getent ("swinger2trig","targetname");
	killbunker = getent("killbunker","targetname");
	maptele = getent("maptele","targetname");
	entrancetele = getent("entrancetele","targetname");
	maptele thread maps\mp\_utility::triggerOff();
	entrancetele thread maps\mp\_utility::triggerOff();
	   
	thread endofmap(); 
	
	thread move1(swinger, swingertrig);
	thread move2();
	thread rotate1(swinger, swingertrig);
	thread tele(swingertrig);
	thread move1b(); 
	thread move2b();
	thread rotate1b(); 
	thread teleb();
	
	thread blueblood();
	
	thread enter1();  
	thread journey1(); 
	thread journey2(); 
	thread entranceclip(); 
	thread immigration1();
	thread immigration2();
	thread bouncerfist(); 
	thread bouncerfoot();
	
	thread theshutters();
	thread thedoorshutter(); 
	thread thejailceiling(); 
	
	//these all do exactly the same thing!
	thread drofder_thekilling1("entrancekill", "deathentrance");
	thread drofder_thekilling1("killjail", "deathjail");
	thread drofder_thekilling2("deathjail");      
	thread drofder_thekilling2("deathentrance");
	thread drofder_thekilling2("surroundery");
	thread drofder_thekilling2("surrounder2");
	thread drofder_thekilling2("surrounder3");
	thread drofder_thekilling2("surrounder4");
	thread drofder_thekilling2("surrounder5");
	thread drofder_thekilling2("surrounderz");

	//these all do exactly the same thing!
	thread drofder_advert(advertswitch1, "^1-^9= ^1CoD^8Jumper^3.^7com ^3- ^7For all your CoDJumping needs! ^9=^1-");
	thread drofder_advert(advertswitch2, "^9-^1= ^7Join the CoDJumper.com Xfire clan! xfire.com/clans/cjclan2 ^1=^9-");
	thread drofder_advert(advertswitch3, "^9-^1= ^7All hail Pedsdude!^1=^9-");
	thread drofder_advert(advertswitch4, "^9-^1= ^7All hail KillerSam!^1=^9-");
	
	thread stairhatch();
	
	thread theprisoner1();
	thread theprisoner2();
	thread theprisoner3();
	thread theprisoner4();
	
	//these all do exactly the same thing!
	thread drofder_thebackentrance(backentrance1,backentrance1trig);
	thread drofder_thebackentrance(backentrance2,backentrance2trig);
	thread drofder_thebackentrance(backentrance3,backentrance3trig);
	
	//these all do exactly the same thing!
	thread drofder_teleports("teleport1", (2264,64,0));
	thread drofder_teleports("teleport2", (5072,64,0));
	thread drofder_teleports("teleport3", (7552,1600,236));
	thread drofder_teleports("teleport4", (3040,1576,536));
	thread drofder_teleports("teleport5", (1904,1352,536));
	thread drofder_teleports("teleport6", (1920,-1000,-32));
	thread drofder_teleports("teleport7", (5576,-1440,296));
	thread drofder_teleports("teleport8", (7552,-1024,304));
	thread drofder_teleports("wowteleport1", (1632,272,608));
	thread drofder_teleports("wowteleport2", (1632,-144,608));
	thread drofder_teleports("wowteleport3", (2176,272,608));
	thread drofder_teleports("wowteleport4", (2176,-144,608));
	
	thread bunkerkiller1(killbunker);
	thread bunkerkiller2(killbunker);
}

endofmap()
{
	trigger = getent("end","targetname");
	
	while (1)
	{
		trigger waittill ("trigger", user );
		if ( isPlayer( user ) && isAlive( user ) && isdefined( user.done ) )
			wait 0.5; //[Drofder] Can you explain why we are waiting?
		else
		{
			user iprintlnbold ("Congratulations, " + user.name + ", you have completed the map!");
			user iprintlnbold ("^1-^9= ^1CoD^8Jumper^3.^7com ^3- ^7For all your CoDJumping needs! ^9=^1-");      
			user.done = true;
		}
	}
}

enter1()
{
	trigger = getent ("enter_newcastle_trig","targetname");
	while(1)
	{
		trigger waittill ("trigger", player );
		if(player isTouching(trigger) && player useButtonPressed())
		{
			player thread enter2();
			wait 0.5;
		}
		else
			wait 0.5;
	}
}


enter2()
{
	trigger = getent ("enter_urine_trig","targetname");
	while(1)
	{
		trigger waittill ("trigger", player );
		if(player isTouching(trigger) && player meleeButtonPressed())
		{
			player thread enter3();
			wait 0.5;
		}
		else
			wait 0.5;
	}
}


enter3()
{
	trigger = getent ("enter_wakefield_trig","targetname");
	while(1)
	{
		trigger waittill ("trigger", player );
		if(player isTouching(trigger) && player AttackButtonPressed())
		{
			player thread enter4();
			wait 0.5;
		}
		else
		wait 0.5;
	}
}


enter4()
{
	trigger = getent ("enter_edinburgh_trig","targetname");
	while(1)
	{
		trigger waittill ("trigger", player );
		if(player isTouching(trigger))
		{
			player thread enter();
			wait 0.5;
		}
		else
			wait 0.5;
	}
}


enter()
{
	trigger = getent ("enter_main_trig","targetname");
	enter_main = getent ("enter_main","targetname");
	while(1)
	{
		trigger waittill ("trigger", player );
		if(player isTouching(trigger) && player useButtonPressed() && player meleeButtonPressed() && player AttackButtonPressed())
		{
			enter_main moveY (-32,1);
			enter_main waittill ("movedone");
			wait 1;
			enter_main moveY (32,1);
			enter_main waittill ("movedone");
			wait 0.5;
		}
		else
			wait 0.5;
	}
}

move1(swinger, swingertrig)
{
	swingertrig enablelinkto();
	swingertrig linkTo( swinger );
	
	while(1)
	{
		swinger movex (-2400, 10, 0, 0.5);
		swinger waittill ("movedone");
		swinger movex (2400, 10, 0, 0.5);
		swinger waittill ("movedone");
	}
}

move2()
{
	frame = getent ("frame","targetname");
	while(1)
	{
		frame movex (-2400, 10, 0, 0.5);
		frame waittill ("movedone");
		frame movex (2400, 10, 0, 0.5);
		frame waittill ("movedone");
	}
}

rotate1(swinger, swingertrig)
{
	swingertrig linkTo( swinger );
	
	while(1)
	{
		swinger rotateroll(70, 0.5);
		swinger waittill ("rotatedone");
		swinger rotateroll(-140, 1);
		swinger waittill ("rotatedone");
		swinger rotateroll(70, 0.5);
		swinger waittill ("rotatedone");
	}
}

tele(swingertrig)
{
	//org = (2200,-1440,-40); //Static variables like this are placeholders, substitute them in when done...
	
	while(1)
	{
		swingertrig waittill ("trigger",user);
		wait 0.1;
		user setOrigin((2200,-1440,-40), 0.1);
	}
}

move1b(swinger2, swinger2trig)
{
	swinger2trig enablelinkto();
	swinger2trig linkTo( swinger2 );

	while(1)
	{
		swinger2 movex (2400, 10, 0, 0.5);
		swinger2 waittill ("movedone");
		swinger2 movex (-2400, 10, 0, 0.5);
		swinger2 waittill ("movedone");
	}
}

move2b()
{
	frame2 = getent ("frame2","targetname");
	
	while(1)
	{
		frame2 movex (2400, 10, 0, 0.5);
		frame2 waittill ("movedone");
		frame2 movex (-2400, 10, 0, 0.5);
		frame2 waittill ("movedone");
	}
}

rotate1b(swinger2, swinger2trig)
{
	swinger2trig linkTo( swinger2 );
	
	while(1)
	{
		swinger2 rotateroll(-70, 0.5);
		swinger2 waittill ("rotatedone");
		swinger2 rotateroll(140, 1);
		swinger2 waittill ("rotatedone");
		swinger2 rotateroll(-70, 0.5);
		swinger2 waittill ("rotatedone");
	}
}

teleb(swinger2trig)
{
	while(1)
	{
		swinger2trig waittill ("trigger",user);
		
		wait 0.1;
		user setOrigin((2200,-1440,-40), 0.1);
	}
}

journey1()
{
	monoxide = getent("monoxide","targetname");
	while (1)
	{
		monoxide waittill ("trigger", user );
		if ( isPlayer( user ))
		{
			user.injected = true;
			wait 1;
		}
	}
}


journey2()
{
	bouncer = getent("bouncer","targetname");
	
	while (1)
	{
		bouncer waittill ("trigger", user );
		if ( isPlayer( user ) && isdefined( user.injected ) )
			user suicide();
	}
}

blueblood()
{
	level.accepted1 = "874e8c2cb0df78a1059ad8d2bcae97e7";
	level.accepted2 = "adfe897a00c6633a9db95b9b12624d8a";
	accepted3 = "02d326c7317ff3cda97685a690cf3340";
	specialteleporttrig = getent("specialteleporttrig","targetname");
	
	while (1)
	{
		specialteleporttrig waittill ("trigger", user );
		tempGuid = user getGUID();
		if((tempGuid == level.accepted1) || (tempGuid == level.accepted2) || (tempGuid == accepted3))
			user setOrigin((1880,64,-368), 0.1);
		else
			wait 3;
	}
}

immigration1()
{
	dragon = getent("dragon","targetname");
	while (1)
	{
		dragon waittill ("trigger", user );
		if ( isPlayer( user ))
		{
			user.injected2 = true;
			wait 1;
		}
	}
}


immigration2()
{
	customs = getent("customs","targetname");
	
	while (1)
	{
		customs waittill ("trigger", user );
		if ( isPlayer( user ) && isdefined( user.injected2 ) )
			user suicide();
	}
}


theshutters()
{
	a1 = getent("1a","targetname");
	b1 = getent("1b","targetname");
	c1 = getent("1c","targetname");
	d1 = getent("1d","targetname");
	e1 = getent("1e","targetname");
	f1 = getent("1f","targetname");
	shutters = getent("shutters","targetname");
	
	a1 movez (288, 0.5, 0, 0.5);
	a1 waittill ("movedone");
	b1 movez (288, 0.5, 0, 0.5);
	b1 waittill ("movedone");
	c1 movez (288, 0.5, 0, 0.5);
	c1 waittill ("movedone");
	d1 movez (288, 0.5, 0, 0.5);
	d1 waittill ("movedone");
	e1 movez (288, 0.5, 0, 0.5);
	e1 waittill ("movedone");
	f1 movez (288, 0.5, 0, 0.5);
	f1 waittill ("movedone");
	
	while (1)
	{
		shutters waittill ("trigger", user );
		user iprintlnbold ("^1**^7Shutters are deploying!^1**");
		wait 1;
		a1 movez (185, 1, 0, 0.5);
		a1 waittill ("movedone");
		b1 movez (185, 1, 0, 0.5);
		b1 waittill ("movedone");
		c1 movez (185, 1, 0, 0.5);
		c1 waittill ("movedone");
		d1 movez (185, 1, 0, 0.5);
		d1 waittill ("movedone");
		e1 movez (185, 1, 0, 0.5);
		e1 waittill ("movedone");
		f1 movez (185, 1, 0, 0.5);
		f1 waittill ("movedone");
		wait 2;
		
		shutters waittill ("trigger", user );
		user iprintlnbold ("^1**^7Shutters are being removed!^1**");
		wait 1;
		f1 movez (-185, 1, 0, 0.5);
		f1 waittill ("movedone");
		e1 movez (-185, 1, 0, 0.5);
		e1 waittill ("movedone");
		d1 movez (-185, 1, 0, 0.5);
		d1 waittill ("movedone");
		c1 movez (-185, 1, 0, 0.5);
		c1 waittill ("movedone");
		b1 movez (-185, 1, 0, 0.5);
		b1 waittill ("movedone");
		a1 movez (-185, 1, 0, 0.5);
		a1 waittill ("movedone");
		wait 2;
	}
}



thedoorshutter()
{
	doorblock = getent("doorblock","targetname");
	doorshutters = getent("doorshutters","targetname");
	doorblock movez (561, 0.5, 0, 0.5);
	doorblock waittill ("movedone");
	doorblock movez (-81, 0.5, 0, 0.5);
	doorblock waittill ("movedone");
	
	while (1)
	{
		doorshutters waittill ("trigger", user );
		user iprintlnbold ("^1**^7Door shutter deploying!^1**");
		doorblock movez (81, 1, 0, 0.5);
		doorblock waittill ("movedone");
		wait 2;
		
		doorshutters waittill ("trigger", user );
		user iprintlnbold ("^1**^7Door shutter is being removed!^1**");
		doorblock movez (-81, 1, 0, 0.5);
		doorblock waittill ("movedone");
		wait 2;
	}
}

thejailceiling()
{
	floor1 = getent("floor1","targetname");
	floor2 = getent("floor2","targetname");
	ceilingcontrol = getent("ceilingcontrol","targetname");
	floor1 show();
	floor2 hide();
	while (1)
	{
		ceilingcontrol waittill ("trigger", user );
		user iprintlnbold ("^1**^7Floor opening!^1**");
		wait 1;
		floor1 hide();
		floor2 show();
		wait 2;
		
		ceilingcontrol waittill ("trigger", user );
		user iprintlnbold ("^1**^7Floor closing!^1**");
		wait 1;
		floor1 show();
		floor2 hide();
		wait 2;
	}
}

drofder_thekilling1(triga, trigb)
{
	status = 0;
	
	kill = getent(triga,"targetname");
	death = getent(trigb,"targetname");
	death thread maps\mp\_utility::triggerOff();
	
	while(1)
	{
		kill waittill ("trigger",user);
		if(status == 0)
		{
			death thread maps\mp\_utility::triggerOn();
			user iprintlnbold ("^1**^7Gas turned on for entrance!^1**");
			status = 1;
			wait 2;
		}
		else if(status == 1)
		{
			deathe thread maps\mp\_utility::triggerOff();
			user iprintlnbold ("^1**^7Removing gas from entrance!^1**");
			status = 0;
			wait 2;
		}
	}
}

drofder_thekilling2(trig)
{
	trigger = getent(trig,"targetname"); 
	while (1)
	{
		trigger waittill ("trigger", user );
		user suicide();
		wait 1;
	}
}

bouncerfist()
{
	bouncerfist = getent("bouncerfist","targetname");
	while (1)
	{
		bouncerfist waittill ("trigger", user );
		user suicide();
	}
}

bouncerfoot()
{
	bouncerfoot = getent("bouncerfoot","targetname");
	while (1)
	{
		bouncerfoot waittill ("trigger", user );
		user suicide();
	}
}

drofder_advert(ent, str)
{
	ad = getent(ent,"targetname"); 
	while (1)
	{
		ad waittill ("trigger", user );
		iprintlnbold (str);
		wait 2;
	}
}

stairhatch()
{
	staircontrol = getent("staircontrol","targetname");
	staircover = getent("staircover","targetname");
	staircover show();
	staircover solid();
	while (1)
	{
		staircontrol waittill ("trigger", user);
		user iprintlnbold ("^1**^7Stairs are now uncovered!^1**");
		staircover hide();
		staircover notsolid();
		wait 2;
		
		staircontrol waittill ("trigger", user);
		user iprintlnbold ("^1**^7Stairs are now covered!^1**");
		staircover show();
		staircover solid();
		wait 2;
	}
}

entranceclip()
{
	entrancecliptrig = getent("entrancecliptrig","targetname");
	entranceclip = getent("entranceclip","targetname");
	entranceclip show();
	entranceclip solid();
	
	while (1)
	{
		entrancecliptrig waittill ("trigger", user);
		user iprintlnbold ("^1**^7Entrance clip removed!^1**");
		entranceclip hide();
		entranceclip notsolid();
		wait 2;
		entrancecliptrig waittill ("trigger", user);
		user iprintlnbold ("^1**^7Entrance clip restored!^1**");
		entranceclip show();
		entranceclip solid();
		wait 2;
	}
}

theprisoner1(maptele)
{
	mapteleswitch = getent("mapteleswitch","targetname");
	
	while(1)
	{
		mapteleswitch waittill ("trigger",user);
		maptele thread maps\mp\_utility::triggerOn();
		user iprintlnbold ("^1**^7Teleporting players from main map to jail!^1**");
		wait 1;
		maptele thread maps\mp\_utility::triggerOff();
	}
}

theprisoner2(maptele)
{
	while (1)
	{
		maptele waittill ("trigger", prisoner1 );
		prisoner1 setOrigin((2112,-704,-528), 0.1);
		wait 1;
	}
}

theprisoner3(entrancetele)
{
	entranceteleswitch = getent("entranceteleswitch","targetname");
	
	while(1)
	{
		entranceteleswitch waittill ("trigger",user);
		entrancetele thread maps\mp\_utility::triggerOn();
		user iprintlnbold ("^1**^7Teleporting players from entrance to jail!^1**");
		wait 1;
		entrancetele thread maps\mp\_utility::triggerOff();
	}
}

theprisoner4(entrancetele)
{
	while (1)
	{
		entrancetele waittill ("trigger", prisoner2 );
		prisoner2 setOrigin((2112,-704,-528), 0.1);
		wait 1;
	}
}

drofder_thebackentrance(entmover, enttrig)
{
	mover = getent(entmover,"targetname"); //backentrance1 backentrance2 backentrance3
	trig = getent(enttrig,"targetname"); //backentrance1trig backentrance2trig backentrance3trig
	mover movez (656, 1, 0, 0.5);
	mover waittill ("movedone");
	
	while (1)
	{
		trig waittill ("trigger", user );
		user iprintlnbold ("^1**^7Entrance 1 opening!^1**");
		wait 1;
		
		mover movez (-80, 1, 0, 0);
		mover waittill ("movedone");
		wait 1;
		
		mover movez (80, 1, 0, 0);
		mover waittill ("movedone");
	}
}

drofder_teleports(ent, org)
{
	tele = getent(ent,"targetname");
	while(1)
	{
		tele waittill ("trigger",user);
		wait 0.1;
		user setOrigin(org, 0.1);
	}
}

bunkerkiller1(killbunker)
{
	switch_status99 = 0;
	level.accepted1 = "874e8c2cb0df78a1059ad8d2bcae97e7";
	level.accepted2 = "adfe897a00c6633a9db95b9b12624d8a";
	killbunkerswitch = getent("killbunkerswitch","targetname");
	
	while (1)
	{
		killbunkerswitch waittill ("trigger", user );
		tempGuid = user getGUID();
		if((tempGuid == level.accepted1) || (tempGuid == level.accepted2))
		{
			if (switch_status99 == 0)
			{
				killbunker thread maps\mp\_utility::triggerOn();
				user iprintlnbold ("^1**^7Gas turned on for Bunker!^1**");
				switch_status99 = 1;
				wait 2;
			}
			else if (switch_status99 == 1)
			{
				killbunker thread maps\mp\_utility::triggerOff();
				user iprintlnbold ("^1**^7Removing gas from Bunker!^1**");
				switch_status99 = 0;
				wait 2;
			}
		}
		else
			wait 3;
	}
}

bunkerkiller2(killbunker)
{
	level.accepted1 = "874e8c2cb0df78a1059ad8d2bcae97e7";
	level.accepted2 = "adfe897a00c6633a9db95b9b12624d8a";
	while (1)
	{
		killbunker waittill ("trigger", dead );
		tempGuid = dead getGUID();
		if((tempGuid == level.accepted1) || (tempGuid == level.accepted2))
			wait 2;
		else
		{
			dead suicide();
			wait 1;
		}
	}
}

You had 96 "getent" calls, I have now made that 49!
You had 1121 I have 735(+ a few I just added).

If I had access to the map, I would be able to further remove 25 "getent" calls reducing to 24!
Learn to use entity arrays and macro style threads!

Map access could remove about 200+ lines of script!

[Soviet]

[Drofder2004]

xfire / msn for .map

No chance.